Toolbar

Summary

Bio::Index::EMBL - Interface for indexing (multiple) EMBL/Swissprot
.dat files (i.e. flat file EMBL/Swissprot format).

Package variables

Included modules

Inherit

Bio::Index::AbstractSeq

Synopsis

    # Complete code for making an index for several
    # EMBL files
    use Bio::Index::EMBL;
    use strict;

    my $Index_File_Name = shift;
    my $inx = Bio::Index::EMBL->new(-filename => $Index_File_Name,
				    -write_flag => 'WRITE');
    $inx->make_index(@ARGV);

    # Print out several sequences present in the index
    # in Fasta format
    use Bio::Index::EMBL;
    use strict;

    my $Index_File_Name = shift;
    my $inx = Bio::Index::EMBL->new(-filename => $Index_File_Name);
    my $out = Bio::SeqIO->new(-format => 'Fasta',-fh => \*STDOUT);

    foreach my $id (@ARGV) {
        my $seq = $inx->fetch($id); # Returns Bio::Seq object
	$out->write_seq($seq);
    }

    # alternatively
    my ($id, $acc);
    my $seq1 = $inx->get_Seq_by_id($id);
    my $seq2 = $inx->get_Seq_by_acc($acc);

Description

Inherits functions for managing dbm files from Bio::Index::Abstract.pm,
and provides the basic funtionallity for indexing EMBL files, and
retrieving the sequence from them. Heavily snaffled from James Gilbert
and his Fasta system. Note: for best results 'use strict'.
The keys are the identifiers in the ID and AC lines.

Methods

Methods description

  Title   : _index_file
  Usage   : $index->_index_file( $file_name, $i )
  Function: Specialist function to index EMBL format files.
            Is provided with a filename and an integer
            by make_index in its SUPER class.
  Example : 
  Returns : 
  Args    :

 Title   : _file_format
 Usage   : Internal function for indexing system
 Function: Provides file format for this database
 Example :
 Returns : 
 Args    :

Methods code

sub _type_stamp {

    return '__EMBL_FLAT__'; # What kind of index are we?

}

sub _version {

    return 0.1;

}

sub _index_file {

    my( $self,
        $file, # File name
        $i     # Index-number of file being indexed
        ) = @_;

    my( $begin, # Offset from start of file of the start
                # of the last found record.
        $id,    # ID of last found record.
	@accs,   # accession of last record. Also put into the index
        );

    $begin = 0;

    open my $EMBL, '<', $file or $self->throw("Can't open file for read : $file");

    # Main indexing loop
    $id = undef;
    @accs = ();
    while (<$EMBL>) {
	if( m{^//} ) {
	    if( ! defined $id ) {
		$self->throw("Got to a end of entry line for an EMBL flat file with no parsed ID. Considering this a problem!");
		next;
	    }
	    if( ! @accs ) {
		$self->warn("For id [$id] in embl flat file, got no accession number. Storing id index anyway");
	    }

	    $self->add_record($id, $i, $begin);

	    foreach my $acc (@accs) {
		if( $acc ne $id ) {
		    $self->add_record($acc, $i, $begin);
		}
	    }
	} elsif (/^ID\s+(\S+)/) {
	    $id = $1;
	    # not sure if I like this. Assummes tell is in bytes.
	    # we could tell before each line and save it.
            $begin = tell($EMBL) - length( $_ );
	
	} elsif (/^AC\s+(.*)?/) {
            push @accs , split (/[; ]+/, $1);
	} else {
	    # do nothing
	}
    }

    close $EMBL;
    return 1;

}

sub _file_format {

   my ($self,@args) = @_;

   return 'EMBL';
}



1;

}

General documentation

User feedback is an integral part of the evolution of this and other
Bioperl modules. Send your comments and suggestions preferably to one
of the Bioperl mailing lists. Your participation is much appreciated.

  bioperl-l@bioperl.org                  - General discussion
  http://bioperl.org/wiki/Mailing_lists  - About the mailing lists

Please direct usage questions or support issues to the mailing list:
bioperl-l@bioperl.org
rather than to the module maintainer directly. Many experienced and
reponsive experts will be able look at the problem and quickly
address it. Please include a thorough description of the problem
with code and data examples if at all possible.

Report bugs to the Bioperl bug tracking system to help us keep track
the bugs and their resolution. Bug reports can be submitted via the
web:

  https://redmine.open-bio.org/projects/bioperl/

Email - birney@sanger.ac.uk

The rest of the documentation details each of the object
methods. Internal methods are usually preceded with a _