Toolbar

Summary

Bio::SeqFeature::PositionProxy - handle features when truncation/revcom sequences span a feature

Package variables

Included modules

Inherit

Bio::Root::Root Bio::SeqFeatureI

Synopsis

   $proxy = Bio::SeqFeature::PositionProxy->new( -loc => $loc,
                                                 -parent => $basefeature);

   $seq->add_SeqFeature($feat);

Description

PositionProxy is a Proxy Sequence Feature to handle truncation
and revcomp without duplicating all the data within the sequence features.
It holds a new location for a sequence feature and the original feature
it came from to provide the additional annotation information.

Methods

Methods description

 Title   : location
 Usage   : my $location = $seqfeature->location()
 Function: returns a location object suitable for identifying location 
           of feature on sequence or parent feature  
 Returns : Bio::LocationI object
 Args    : none

 Title   : parent
 Usage   : my $sf = $proxy->parent()
 Function: returns the seqfeature parent of this proxy
 Returns : Bio::SeqFeatureI object
 Args    : none

 Title   : start
 Usage   : $start = $feat->start
           $feat->start(20)
 Function: Get
 Returns : integer
 Args    : none

 Title   : end
 Usage   : $end = $feat->end
           $feat->end($end)
 Function: get
 Returns : integer
 Args    : none

 Title   : length
 Usage   :
 Function:
 Example :
 Returns :
 Args    :

 Title   : strand
 Usage   : $strand = $feat->strand()
           $feat->strand($strand)
 Function: get/set on strand information, being 1,-1 or 0
 Returns : -1,1 or 0
 Args    : none

 Title   : attach_seq
 Usage   : $sf->attach_seq($seq)
 Function: Attaches a Bio::Seq object to this feature. This
           Bio::Seq object is for the *entire* sequence: ie
           from 1 to 10000
 Example :
 Returns : TRUE on success
 Args    :

 Title   : seq
 Usage   : $tseq = $sf->seq()
 Function: returns the truncated sequence (if there) for this
 Example :
 Returns : sub seq on attached sequence bounded by start & end
 Args    : none

 Title   : entire_seq
 Usage   : $whole_seq = $sf->entire_seq()
 Function: gives the entire sequence that this seqfeature is attached to
 Example :
 Returns :
 Args    :

 Title   : seqname
 Usage   : $obj->seq_id($newval)
 Function: There are many cases when you make a feature that you
           do know the sequence name, but do not know its actual
           sequence. This is an attribute such that you can store
           the seqname.

           This attribute should *not* be used in GFF dumping, as
           that should come from the collection in which the seq
           feature was found.
 Returns : value of seqname
 Args    : newvalue (optional)

 Title   : primary_tag
 Usage   : $tag = $feat->primary_tag()
 Function: Returns the primary tag for a feature,
           eg 'exon'
 Returns : a string 
 Args    : none

 Title   : source_tag
 Usage   : $tag = $feat->source_tag()
 Function: Returns the source tag for a feature,
           eg, 'genscan' 
 Returns : a string 
 Args    : none

 Title   : has_tag
 Usage   : $tag_exists = $self->has_tag('some_tag')
 Function: 
 Returns : TRUE if the specified tag exists, and FALSE otherwise
 Args    :

 Title   : get_tag_values
 Usage   : @values = $self->get_tag_values('some_tag')
 Function: 
 Returns : An array comprising the values of the specified tag.
 Args    :

 Title   : get_all_tags
 Usage   : @tags = $feat->get_all_tags()
 Function: gives all tags for this feature
 Returns : an array of strings
 Args    : none

Methods code

sub new {

    my ($caller, @args) = @_;
    my $self = $caller->SUPER::new(@args);

    my ($feature,$location) = $self->_rearrange([qw(PARENT LOC)],@args);

    if( !defined $feature || !ref $feature || !$feature->isa('Bio::SeqFeatureI') ) {
      $self->throw("Must have a parent feature, not a [$feature]");
    }

    if( $feature->isa("Bio::SeqFeature::PositionProxy") ) {
      $feature = $feature->parent();
    }

    if( !defined $location || !ref $location || !$location->isa('Bio::LocationI') ) {
      $self->throw("Must have a location, not a [$location]");
    }


    return $self;

}

sub location {

    my($self, $value ) = @_;  

    if (defined($value)) {
        unless (ref($value) and $value->isa('Bio::LocationI')) {
            $self->throw("object $value pretends to be a location but ".
                "does not implement Bio::LocationI");
        }
        $self->{'_location'} = $value;
    }
    elsif (! $self->{'_location'}) {
        # guarantees a real location object is returned every time
        $self->{'_location'} = Bio::Location::Simple->new();
    }
    return $self->{'_location'};

}

sub parent {

    my($self, $value ) = @_;  

    if (defined($value)) {
        unless (ref($value) and $value->isa('Bio::SeqFeatureI')) {
            $self->throw("object $value pretends to be a location but ".
                "does not implement Bio::SeqFeatureI");
        }
        $self->{'_parent'} = $value;
    }

    return $self->{'_parent'};

}

sub start {

   my ($self,$value) = @_;
   return $self->location->start($value);

}

sub end {

   my ($self,$value) = @_;
   return $self->location->end($value);

}

sub length {

   my ($self) = @_;
   return $self->end - $self->start() + 1;

}

sub strand {

   my ($self,$value) = @_;
   return $self->location->strand($value);

}

sub attach_seq {

   my ($self, $seq) = @_;

   if ( !defined $seq || !ref $seq || ! $seq->isa("Bio::PrimarySeqI") ) {
       $self->throw("Must attach Bio::PrimarySeqI objects to SeqFeatures");
   }

   $self->{'_gsf_seq'} = $seq;

   # attach to sub features if they want it

   foreach my $sf ( $self->sub_SeqFeature() ) {
       if ( $sf->can("attach_seq") ) {
           $sf->attach_seq($seq);
       }
   }
   return 1;

}

sub seq {

   my ($self, $arg) = @_;

   if ( defined $arg ) {
       $self->throw("Calling SeqFeature::PositionProxy->seq with an argument. You probably want attach_seq");
   }

   if ( ! exists $self->{'_gsf_seq'} ) {
       return;
   }

   # assumming our seq object is sensible, it should not have to yank
   # the entire sequence out here.

   my $seq = $self->{'_gsf_seq'}->trunc($self->start(), $self->end());


   if ( $self->strand == -1 ) {
       $seq = $seq->revcom;
   }

   return $seq;

}

sub entire_seq {

   my ($self) = @_;

   return unless exists($self->{'_gsf_seq'});
   return $self->{'_gsf_seq'};

}

sub seqname {

    my ($obj,$value) = @_;
    if ( defined $value ) {
        $obj->{'_gsf_seqname'} = $value;
    }
    return $obj->{'_gsf_seqname'};

}

sub primary_tag {

   my ($self,@args) = @_;

   return $self->parent->primary_tag();

}

sub source_tag {

   my ($self) = @_;

   return $self->parent->source_tag();

}

sub has_tag {

   my ($self,$tag) = @_;

   return $self->parent->has_tag($tag);

}

sub get_tag_values {

   my ($self,$tag) = @_;

   return $self->parent->get_tag_values($tag);

}

sub get_all_tags {

   my ($self) = @_;

   return $self->parent->all_tags();
}

1;

}

General documentation

User feedback is an integral part of the evolution of this and other
Bioperl modules. Send your comments and suggestions preferably to one
of the Bioperl mailing lists. Your participation is much appreciated.

  bioperl-l@bioperl.org                  - General discussion
  http://bioperl.org/wiki/Mailing_lists  - About the mailing lists

Please direct usage questions or support issues to the mailing list:
bioperl-l@bioperl.org
rather than to the module maintainer directly. Many experienced and
reponsive experts will be able look at the problem and quickly
address it. Please include a thorough description of the problem
with code and data examples if at all possible.

Report bugs to the Bioperl bug tracking system to help us keep track
the bugs and their resolution. Bug reports can be submitted via the
web:

  https://redmine.open-bio.org/projects/bioperl/

Ewan Birney <birney@sanger.ac.uk>

This class has been written with an eye out of inheritence. The fields
the actual object hash are:

   _gsf_tag_hash  = reference to a hash for the tags
   _gsf_sub_array = reference to an array for sub arrays
   _gsf_start     = scalar of the start point
   _gsf_end       = scalar of the end point
   _gsf_strand    = scalar of the strand

The rest of the documentation details each of the object
methods. Internal methods are usually preceded with a _

These functions chain back to the parent for all non sequence related stuff.