Summary

Bio::Cluster::ClusterFactory - Instantiates a new Bio::ClusterI (or derived class) through a factory

Package variables

Included modules

Inherit

Bio::Factory::ObjectFactoryI Bio::Root::Root

Synopsis

    use Bio::Cluster::ClusterFactory;
    # if you don't provide a default type, the factory will try
    # some guesswork based on display_id and namespace
    my $factory = new Bio::Cluster::ClusterFactory(-type => 'Bio::Cluster::UniGene');
    my $clu = $factory->create_object(-description => 'NAT',
                                      -display_id  => 'Hs.2');

Description

This object will build Bio::ClusterI objects generically.

Methods

Methods description

 Title   : new
 Usage   : my $obj = new Bio::Cluster::ClusterFactory();
 Function: Builds a new Bio::Cluster::ClusterFactory object 
 Returns : Bio::Cluster::ClusterFactory
 Args    : -type => string, name of a ClusterI derived class.
                    If not provided, the factory will have to guess
                    from ID and namespace, which may or may not be
                    successful.

 Title   : create_object
 Usage   : my $seq = $factory->create_object();
 Function: Instantiates new Bio::ClusterI (or one of its child classes)

           This object allows us to genericize the instantiation of
           cluster objects.

 Returns : Bio::ClusterI compliant object
           The return type is configurable using new(-type =>"...").
 Args    : initialization parameters specific to the type of cluster
           object we want.  Typically 
           -display_id  => $name
           -description => description of the cluster
           -members     => arrayref, members of the cluster

 Title   : type
 Usage   : $obj->type($newval)
 Function: Get/set the type of Bio::ClusterI object to be created.

           This may be changed at any time during the lifetime of this
           factory.

 Returns : value of type
 Args    : newvalue (optional)

 Title   : _guess_type
 Usage   :
 Function: Guesses the right type of Bio::ClusterI implementation
           based on initialization parameters for the prospective
           object.
 Example :
 Returns : the type (a string, the module name)
 Args    : initialization parameters to be passed to the prospective
           cluster object

Methods code

sub new {

    my($class,@args) = @_;

    my $self = $class->SUPER::new(@args);
  
    my ($type) = $self->_rearrange([qw(TYPE)], @args);

    $self->{'_loaded_types'} = {};
    $self->type($type) if $type;

    return $self;

}

sub create_object {

   my ($self,@args) = @_;

   my $type = $self->type();
   if(! $type) {
       # we need to guess this
       $type = $self->_guess_type(@args);
       if(! $type) {
	   $self->throw("No cluster type set and unable to guess.");
       }
       # load dynamically if it hasn't been loaded yet
       if(! $self->{'_loaded_types'}->{$type}) {
	   eval {
	       $self->_load_module($type);
	       $self->{'_loaded_types'}->{$type} = 1;
	   };
	   if($@) {
	       $self->throw("Bio::ClusterI implementation $type ".
			    "failed to load: ".$@);
	   }
       }
   }
   return $type->new(-verbose => $self->verbose, @args);

}

sub type {

    my $self = shift;

    if(@_) {
	my $type = shift;
	if($type && (! $self->{'_loaded_types'}->{$type})) {
	    eval {
		$self->_load_module($type);
	    };
	    if( $@ ) {
		$self->throw("Cluster implementation '$type' failed to load: ".
			     $@);
	    }
	    my $a = bless {},$type;
	    if( ! $a->isa('Bio::ClusterI') ) {
		$self->throw("'$type' does not implement Bio::ClusterI. ".
			     "Too bad.");
	    }
	    $self->{'_loaded_types'}->{$type} = 1;
	}
	return $self->{'type'} = $type;
    }
    return $self->{'type'};

}

sub _guess_type {

    my ($self,@args) = @_;
    my $type;

    # we can only guess from a certain number of arguments
    my ($dispid, $ns, $members) =
	$self->_rearrange([qw(DISPLAY_ID
			      NAMESPACE
			      MEMBERS
			      )], @args);
    # Unigene namespace or ID?
    if($ns && (lc($ns) eq "unigene")) {
	$type = 'Bio::Cluster::UniGene';
    } elsif($dispid && ($dispid =~ /^Hs\.[0-9]/)) {
	$type = 'Bio::Cluster::UniGene';
    }
    # what else could we look for?
    return $type;

}

General documentation

User feedback is an integral part of the evolution of this and other
Bioperl modules. Send your comments and suggestions preferably to
the Bioperl mailing list. Your participation is much appreciated.

  bioperl-l@bioperl.org              - General discussion
  http://bioperl.org/MailList.shtml  - About the mailing lists

Report bugs to the Bioperl bug tracking system to help us keep track
of the bugs and their resolution. Bug reports can be submitted via
email or the web:

  bioperl-bugs@bioperl.org
  http://bugzilla.bioperl.org/

Email hlapp at gmx.net

This is mostly copy-and-paste with subsequent adaptation from
Bio::Seq::SeqFactory by Jason Stajich. Most credits should in fact go
to him.

The rest of the documentation details each of the object methods.
Internal methods are usually preceded with a _