Bio AlignIO
SummaryIncluded librariesPackage variablesSynopsisDescriptionGeneral documentationMethods
Toolbar
WebCvs
Summary
Bio::AlignIO - Handler for AlignIO Formats
Package variables
No package variables defined.
Included modules
Bio::LocatableSeq
Bio::Seq
Bio::SimpleAlign
Bio::Tools::GuessSeqFormat
Inherit
Bio::Root::IO Bio::Root::Root
Synopsis
    use Bio::AlignIO;

    $inputfilename = "testaln.fasta";
    $in  = Bio::AlignIO->new(-file   => $inputfilename ,
                             -format => 'fasta');
    $out = Bio::AlignIO->new(-file   => ">out.aln.pfam" ,
                             -format => 'pfam');

    while ( my $aln = $in->next_aln() ) {
        $out->write_aln($aln);
    }

    # OR

    use Bio::AlignIO;

    open MYIN,"testaln.fasta";
    $in  = Bio::AlignIO->newFh(-fh     => \*MYIN,
                               -format => 'fasta');
    open my $MYOUT, '>', 'testaln.pfam';
    $out = Bio::AlignIO->newFh(-fh     =>  $MYOUT,
                               -format => 'pfam');

    # World's smallest Fasta<->pfam format converter:
    print $out $_ while <$in>;
Description
Bio::AlignIO is a handler module for the formats in the AlignIO set,
for example, Bio::AlignIO::fasta. It is the officially sanctioned way
of getting at the alignment objects. The resulting alignment is a
Bio::Align::AlignI-compliant object.
The idea is that you request an object for a particular format.
All the objects have a notion of an internal file that is read
from or written to. A particular AlignIO object instance is configured
for either input or output, you can think of it as a stream object.
Each object has functions:
   $stream->next_aln();
And:
   $stream->write_aln($aln);
Also:
   $stream->type() # returns 'INPUT' or 'OUTPUT'
As an added bonus, you can recover a filehandle that is tied to the
AlignIO object, allowing you to use the standard <> and print
operations to read and write alignment objects:
    use Bio::AlignIO;

    # read from standard input
    $stream = Bio::AlignIO->newFh(-format => 'Fasta');

    while ( $aln = <$stream> ) {
	     # do something with $aln
    }
And:
    print $stream $aln; # when stream is in output mode
Bio::AlignIO is patterned on the Bio::SeqIO module and shares
most of its features. One significant difference is that
Bio::AlignIO usually handles IO for only a single alignment at a time,
whereas Bio::SeqIO handles IO for multiple sequences in a single stream.
The principal reason for this is that whereas simultaneously handling
multiple sequences is a common requirement, simultaneous handling of
multiple alignments is not. The only current exception is format
bl2seq which parses results of the BLAST bl2seq program and which
may produce several alignment pairs. This set of alignment pairs can
be read using multiple calls to next_aln.
Methods
newDescriptionCode
newFhDescriptionCode
fhDescriptionCode
_initialize
No description
Code
_load_format_moduleDescriptionCode
next_alnDescriptionCode
write_alnDescriptionCode
_guess_formatDescriptionCode
DESTROY
No description
Code
TIEHANDLEDescriptionCode
READLINE
No description
Code
PRINT
No description
Code
force_displayname_flatDescriptionCode
alphabetDescriptionCode
Methods description
newcode    nextTop
 Title   : new
 Usage   : $stream = Bio::AlignIO->new(-file => $filename,
                                       -format => 'Format')
 Function: Returns a new seqstream
 Returns : A Bio::AlignIO::Handler initialised with
           the appropriate format
 Args    : -file => $filename
           -format => format
           -fh => filehandle to attach to
           -displayname_flat => 1 [optional]
                                to force the displayname to not show start/end
                                information
newFhcodeprevnextTop
 Title   : newFh
 Usage   : $fh = Bio::AlignIO->newFh(-file=>$filename,-format=>'Format')
 Function: does a new() followed by an fh()
 Example : $fh = Bio::AlignIO->newFh(-file=>$filename,-format=>'Format')
           $sequence = <$fh>;   # read a sequence object
           print $fh $sequence; # write a sequence object
 Returns : filehandle tied to the Bio::AlignIO::Fh class
 Args    :
fhcodeprevnextTop
 Title   : fh
 Usage   : $obj->fh
 Function:
 Example : $fh = $obj->fh;      # make a tied filehandle
           $sequence = <$fh>;   # read a sequence object
           print $fh $sequence; # write a sequence object
 Returns : filehandle tied to the Bio::AlignIO::Fh class
 Args    :
_load_format_modulecodeprevnextTop
 Title   : _load_format_module
 Usage   : *INTERNAL AlignIO stuff*
 Function: Loads up (like use) a module at run time on demand
 Example :
 Returns :
 Args    :
next_alncodeprevnextTop
 Title   : next_aln
 Usage   : $aln = stream->next_aln
 Function: reads the next $aln object from the stream
 Returns : a Bio::Align::AlignI compliant object
 Args    :
write_alncodeprevnextTop
 Title   : write_aln
 Usage   : $stream->write_aln($aln)
 Function: writes the $aln object into the stream
 Returns : 1 for success and 0 for error
 Args    : Bio::Seq object
_guess_formatcodeprevnextTop
 Title   : _guess_format
 Usage   : $obj->_guess_format($filename)
 Function:
 Example :
 Returns : guessed format of filename (lower case)
 Args    :
TIEHANDLE(), READLINE(), PRINT()codeprevnextTop
These provide the tie interface. See perltie for more details.
force_displayname_flatcodeprevnextTop
 Title   : force_displayname_flat
 Usage   : $obj->force_displayname_flat($newval)
 Function:
 Example :
 Returns : value of force_displayname_flat (a scalar)
 Args    : on set, new value (a scalar or undef, optional)
alphabetcodeprevnextTop
 Title   : alphabet
 Usage   : $obj->alphabet($newval)
 Function: Get/Set alphabet for purpose of passing to Bio::LocatableSeq creation
 Example : $obj->alphabet('dna');
 Returns : value of alphabet (a scalar)
 Args    : on set, new value (a scalar or undef, optional)
Methods code
newdescriptionprevnextTop
sub new {
    my ($caller,@args) = @_;
    my $class = ref($caller) || $caller;

    # or do we want to call SUPER on an object if $caller is an
    # object?
    if( $class =~ /Bio::AlignIO::(\S+)/ ) {
	my ($self) = $class->SUPER::new(@args);
	$self->_initialize(@args);
	return $self;
    } else {

	my %param = @args;
	@param{ map { lc $_ } keys %param } = values %param; # lowercase keys
	my $format = $param{'-format'} ||
	    $class->_guess_format( $param{-file} || $ARGV[0] );
        unless ($format) {
            if ($param{-file}) {
                $format = Bio::Tools::GuessSeqFormat->new(-file => $param{-file}||$ARGV[0] )->guess;
            }
            elsif ($param{-fh}) {
                $format = Bio::Tools::GuessSeqFormat->new(-fh => $param{-fh}||$ARGV[0] )->guess;
            }
        }
	$format = "\L$format";	# normalize capitalization to lower case
        $class->throw("Unknown format given or could not determine it [$format]")
            unless $format;

	return unless( $class->_load_format_module($format) );
	return "Bio::AlignIO::$format"->new(@args);
    }
}
newFhdescriptionprevnextTop
sub newFh {
  my $class = shift;
  return unless my $self = $class->new(@_);
  return $self->fh;
}
fhdescriptionprevnextTop
sub fh {
  my $self = shift;
  my $class = ref($self) || $self;
  my $s = Symbol::gensym;
  tie $$s,$class,$self;
  return $s;
}
_initializedescriptionprevnextTop
sub _initialize {
  my($self,@args) = @_;
  my ($flat,$alphabet,$width) = $self->_rearrange([qw(DISPLAYNAME_FLAT ALPHABET WIDTH)],
				 @args);
  $self->force_displayname_flat($flat) if defined $flat;
  $self->alphabet($alphabet);
  $self->width($width) if defined $width;
  $self->_initialize_io(@args);
  1;
}
_load_format_moduledescriptionprevnextTop
sub _load_format_module {
  my ($self,$format) = @_;
  my $module = "Bio::AlignIO::" . $format;
  my $ok;

  eval {
      $ok = $self->_load_module($module);
  };
  if ( $@ ) {
    print STDERR <<END;
$self: $format cannot be found
Exception $@
For more information about the AlignIO system please see the AlignIO docs.
This includes ways of checking for formats at compile time, not run time
END
  ;
    return;
  }
  return 1;
}
next_alndescriptionprevnextTop
sub next_aln {
   my ($self,$aln) = @_;
   $self->throw("Sorry, you cannot read from a generic Bio::AlignIO object.");
}
write_alndescriptionprevnextTop
sub write_aln {
    my ($self,$aln) = @_;
    $self->throw("Sorry, you cannot write to a generic Bio::AlignIO object.");
}
_guess_formatdescriptionprevnextTop
sub _guess_format {
my $class = shift;
   return unless $_ = shift;
   return 'clustalw'    if /\.aln$/i;
   return 'emboss'      if /\.(water|needle)$/i;
   return 'metafasta'   if /\.metafasta$/;
   return 'fasta'       if /\.(fasta|fast|seq|fa|fsa|nt|aa)$/i;
   return 'maf'         if /\.maf/i;
   return 'mega'        if /\.(meg|mega)$/i;
   return 'meme'        if /\.meme$/i;
   return 'msf'         if /\.(msf|pileup|gcg)$/i;
   return 'nexus'       if /\.(nexus|nex)$/i;
   return 'pfam'        if /\.(pfam|pfm)$/i;
   return 'phylip'      if /\.(phylip|phlp|phyl|phy|ph)$/i;
   return 'psi'         if /\.psi$/i;
   return 'stockholm'   if /\.stk$/i;
   return 'selex'       if /\.(selex|slx|selx|slex|sx)$/i;
   return 'xmfa'        if /\.xmfa$/i;
}
DESTROYdescriptionprevnextTop
sub DESTROY {
    my $self = shift;
    $self->close();
}
TIEHANDLEdescriptionprevnextTop
sub TIEHANDLE {
  my $class = shift;
  return bless {'alignio' => shift},$class;
}
READLINEdescriptionprevnextTop
sub READLINE {
  my $self = shift;
  return $self->{'alignio'}->next_aln() unless wantarray;
  my (@list,$obj);
  push @list,$obj  while $obj = $self->{'alignio'}->next_aln();
  return @list;
}
PRINTdescriptionprevnextTop
sub PRINT {
  my $self = shift;
  $self->{'alignio'}->write_aln(@_);
}
force_displayname_flatdescriptionprevnextTop
sub force_displayname_flat {
    my $self = shift;
    return $self->{'_force_displayname_flat'} = shift if @_;
    return $self->{'_force_displayname_flat'} || 0;
}
alphabetdescriptionprevnextTop
sub alphabet {
    my $self = shift;
    my $value = shift;
    if ( defined $value ) {
        $self->throw("Invalid alphabet $value") unless $value eq 'rna' || $value eq 'protein' || $value eq 'dna';
        $self->{'_alphabet'} = $value;
    }
    return $self->{'_alphabet'};
}


1;
}
General documentation
CONSTRUCTORSTop
Bio::AlignIO->new()Top
   $seqIO = Bio::AlignIO->new(-file => 'filename',   -format=>$format);
   $seqIO = Bio::AlignIO->new(-fh   => \*FILEHANDLE, -format=>$format);
   $seqIO = Bio::AlignIO->new(-format => $format);
   $seqIO = Bio::AlignIO->new(-fh => \*STDOUT, -format => $format);
The new class method constructs a new Bio::AlignIO object.
The returned object can be used to retrieve or print alignment
objects. new accepts the following parameters:
    -file
    A file path to be opened for reading or writing. The usual Perl
conventions apply:
   'file'       # open file for reading
   '>file'      # open file for writing
   '>>file'     # open file for appending
   '+<file'     # open file read/write
   'command |'  # open a pipe from the command
   '| command'  # open a pipe to the command
    -fh
    You may provide new() with a previously-opened filehandle. For
example, to read from STDIN:
   $seqIO = Bio::AlignIO->new(-fh => \*STDIN);
    Note that you must pass filehandles as references to globs.
    If neither a filehandle nor a filename is specified, then the module
will read from the @ARGV array or STDIN, using the familiar <>
semantics.
    -format
    Specify the format of the file. Supported formats include:
   bl2seq      Bl2seq Blast output
   clustalw    clustalw (.aln) format
   emboss      EMBOSS water and needle format
   fasta       FASTA format
   maf         Multiple Alignment Format
   mase        mase (seaview) format
   mega        MEGA format
   meme        MEME format
   msf         msf (GCG) format
   nexus       Swofford et al NEXUS format
   pfam        Pfam sequence alignment format
   phylip      Felsenstein PHYLIP format
   prodom      prodom (protein domain) format
   psi         PSI-BLAST format
   selex       selex (hmmer) format
   stockholm   stockholm format
    Currently only those formats which were implemented in Bio::SimpleAlign
have been incorporated into Bio::AlignIO. Specifically, mase, stockholm
and prodom have only been implemented for input. See the specific module
(e.g. Bio::AlignIO::prodom) for notes on supported versions.
    If no format is specified and a filename is given, then the module
will attempt to deduce it from the filename suffix. If this is unsuccessful,
fasta format is assumed.
    The format name is case insensitive; FASTA, Fasta and fasta are
all treated equivalently.
Bio::AlignIO->newFh()Top
   $fh = Bio::AlignIO->newFh(-fh   => \*FILEHANDLE, -format=>$format);
   # read from STDIN or use @ARGV:
   $fh = Bio::AlignIO->newFh(-format => $format);
This constructor behaves like new, but returns a tied filehandle
rather than a Bio::AlignIO object. You can read sequences from this
object using the familiar <> operator, and write to it using
print. The usual array and $_ semantics work. For example, you can
read all sequence objects into an array like this:
  @sequences = <$fh>;
Other operations, such as read(), sysread(), write(), close(), and printf()
are not supported.
 -flush
 By default, all files (or filehandles) opened for writing alignments
will be flushed after each write_aln() making the file immediately
usable. If you do not need this facility and would like to marginally
improve the efficiency of writing multiple sequences to the same file
(or filehandle), pass the -flush option '0' or any other value that
evaluates as defined but false:
  my $clustal = Bio::AlignIO->new( -file   => "<prot.aln",
                                   -format => "clustalw" );
  my $msf = Bio::AlignIO->new(-file   => ">prot.msf",
                              -format => "msf",
                              -flush  => 0 ); # go as fast as we can!
  while($seq = $clustal->next_aln) { $msf->write_aln($seq) }
OBJECT METHODSTop
See below for more detailed summaries. The main methods are:
$alignment = $AlignIO->next_aln()Top
Fetch an alignment from a formatted file.
$AlignIO->write_aln($aln)Top
Write the specified alignment to a file..
FEEDBACKTop
Mailing ListsTop
User feedback is an integral part of the evolution of this and other
Bioperl modules. Send your comments and suggestions preferably to one
of the Bioperl mailing lists. Your participation is much appreciated.
  bioperl-l@bioperl.org                  - General discussion
  http://bioperl.org/wiki/Mailing_lists  - About the mailing lists
Support Top
Please direct usage questions or support issues to the mailing list:
bioperl-l@bioperl.org
rather than to the module maintainer directly. Many experienced and
reponsive experts will be able look at the problem and quickly
address it. Please include a thorough description of the problem
with code and data examples if at all possible.
Reporting BugsTop
Report bugs to the Bioperl bug tracking system to help us keep track
the bugs and their resolution. Bug reports can be submitted via the
web:
  https://redmine.open-bio.org/projects/bioperl/
AUTHOR - Peter SchattnerTop
Email: schattner@alum.mit.edu
CONTRIBUTORSTop
Jason Stajich, jason@bioperl.org
APPENDIXTop
The rest of the documentation details each of the object
methods. Internal methods are usually preceded with a _
formatTop
 Title   : format
 Usage   : $format = $stream->format()
 Function: Get the alignment format
 Returns : alignment format
 Args    : none